A partir do Delphi XE2 Update 2 isso não é mais problema, o suporte a blob no método CopyReaderToClientDataSet foi implementando.

Para saber como utilizar o método CopyReaderToClientDataSet na prática leia o artigo “Copiando estrutura e dados de um DBXReader para ClientDataSet  - DataSnap“

Posts relacionados

• Conectando ao PostgreSQL com dbExpress ODBC driver
• Monitoramento e controle de conexões em DataSnap XE2
• Implementando cache de dados em servidores DataSnap
• Exemplos e slides do Delphi Meeting 2011
• Vídeos sobre DataSnap para 2011 – o que você gostaria de ver?
• Apresentações do Delphi Conference 2010 disponível para download

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

Para mostrar na prática como funciona, criei uma aplicação FireMonkey que conecta a uma base de dados PostgreSQL.

Como requisito, você precisa instalar na máquina onde a aplicação será executada o driver ODBC do PostgreSQL, que pode ser baixado aqui. Vale lembrar que aplicações compiladas como 32-bit requerem a versão 32-bit do driver ODBC da base de dados a ser utilizada, para aplicações 64-bit será necessário o driver ODBC 64-bit.

Após instalado o driver, crie e configure o User DSN ou System DSN no ODBC Data Source Administrator (odbcad32.exe):

Instruções para windows 64-bit

• Para aplicações 32-bit use o c:\Windows\SysWOW64\odbcad32.exe
• Para aplicações 64-bit use o c:\Windows\system32\odbcad32.exe

Instruções para windows 32-bit

• Use o c:\Windows\system32\odbcad32.exe

O próximo passe é criar um alias dbExpress ODBC no Data Explorer, onde Database Name é o nome do Data Source criado anteriormente, no meu exemplo este Data Source se chama PostgreSQL35W. Todas as informações relacionada a qual base de dados conectar, usuário e senha já foram configuradas no Data Source, você pode sobrescrever o usuário e senha na conexão dbExpress.

Supondo que você já saiba como utilizar os componentes SQLConnection, DataSetProvider e ClientDataSet ou SimpleDataSet e DataSource, basta conectá-los da mesma forma que você sempre fez com aplicações que utilizam os componentes dbExpress. A configuração do SQLConnection será configurada conforme abaixo:

  object SQLConnection1: TSQLConnection
    ConnectionName = 'PostgreSQLOdbc'
    DriverName = 'ODBC'
    LoginPrompt = False
    Params.Strings = (
      'drivername=ODBC'
      'Database=PostgreSQL35W')
  end

Além de poder utilizar os componentes dbExpress em aplicações VCL e FireMonkey, você pode utilizar o dbExpress framework para conectar a bancos de dados que não tenham um driver nativo. A figura abaixo mostra a aplicação FireMonkey conectada a PostgreSQL através do dbExpress ODBC driver.

Download do código fonte disponível aqui.

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Vídeo: Delphi XE2 e FireMonkey app no Windows, Mac e iOS
• Usando expressões regulares em aplicações FireMonkey com C++Builder
• Usando dbExpress Framework no Windows e Mac com C++Builder
• Hora de seguir em frente
• Apresentações do Delphi Conference 2011 disponíveis para download

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

O código abaixo cria 2 tabelas: Country e State, adiciona chave primária em ambas as tabelas e um relacionamento (foreign key) entre as duas, tudo …

procedure CreateSchema(conn: TSQLConnection);
var
  Provider: TDBXDataExpressMetaDataProvider;
  Country, State: TDBXMetaDataTable;
  IdCountryField,
  IdField: TDBXInt32Column;
  StrField : TDBXUnicodeVarCharColumn;
begin
  Provider := DBXGetMetaProvider(conn.DBXConnection);

  // Country
  Writeln('Creating Table - Country ....................');
  Country := TDBXMetaDataTable.Create;
  Country.TableName := 'COUNTRY';

  IdCountryField := TDBXInt32Column.Create('COUNTRYID');
  IdCountryField.Nullable := false;
  IdCountryField.AutoIncrement := true;
  Country.AddColumn(IdCountryField);

  StrField := TDBXUnicodeVarCharColumn.Create('COUNTRYNAME', 50);
  StrField.Nullable := False;

  Country.AddColumn(StrField);

  Provider.CreateTable(Country);

  // Set COUNTRYID as Primary Key
  AddPrimaryKey(Provider, Country.TableName, IdCountryField.ColumnName);

  // Set Unique Index for COUNTRYNAME
  AddUniqueIndex(Provider, Country.TableName, StrField.ColumnName);

  // State
  Writeln('Creating Table - State ....................');
  State := TDBXMetaDataTable.Create;
  State.TableName := 'STATE';

  IdField := TDBXInt32Column.Create('STATEID');
  IdField.Nullable := false;
  IdField.AutoIncrement := true;
  State.AddColumn(IdField);

  StrField := TDBXUnicodeVarCharColumn.Create('SHORTNAME', 2);
  StrField.Nullable := False;
  State.AddColumn(StrField);

  StrField := TDBXUnicodeVarCharColumn.Create('STATENAME', 50);
  StrField.Nullable := False;
  State.AddColumn(StrField);

  State.AddColumn(IdCountryField);

  Provider.CreateTable(State);

  // Set STATEID as Primary Key
  AddPrimaryKey(Provider, State.TableName, idField.ColumnName);

  // Set Unique Index for STATENAME
  AddUniqueIndex(Provider, State.TableName, StrField.ColumnName);

  AddForeignKey(Provider, State.TableName, IdCountryField.ColumnName,
                Country.TableName, IdCountryField.ColumnName);

  FreeAndNil(Provider);
  FreeAndNil(Country);

end;

Download do código fontes completo aqui.

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Apresentações do Delphi Conference 2010 disponível para download
• Como trabalhar com multiplas transações utilizando dbExpress Framework
• Como utilizar parâmetros em dbExpress (DBX) Framework
• Copiando estrutura e dados de um DBXReader para ClientDataSet – DataSnap 2010

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

Para efetuar o download das apresentações você precisa de uma conta no EDN (Embarcadero Developer Network), que é grátis, caso você já a tenha, efetue o login e tenha acesso ao melhor conteúdo já apresentado sobre Delphi.

Artigo do EDN com todas as apresentações, clique aqui.

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Exemplos e slides do Delphi Meeting 2011
• Teste nosso servidor DataSnap XE instalado no Amazon Cloud
• DataSnap XE e Windows Azure – RAD Studio XE Preview #3
• Copiando estrutura e dados de um DBXReader para ClientDataSet – DataSnap 2010
• Utilizando generics para transformação genérica de Objetos em DataSnap 2010

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

O método TDBXConnection.BeginTransaction inicia uma transação no banco de dados, o tipo desta transação irá depender do parâmetro a ser passado durante a criação da transação, estes tipos podem ser:

• TDBXIsolations.ReadCommitted
• TDBXIsolations.RepeatableRead
• TDBXIsolations.DirtyRead
• TDBXIsolations.Serializable
• TDBXIsolations.SnapShot

Você pode consultar a documentação do RAD Studio online e entender cada tipo de isolamente transacional aqui. Importante lembrar que o isolamento transacional irá variar de banco para banco, verifica quais o seu banco de dados suporta.

Ao iniciar uma transação o método BeginTransaction retornará um objeto do tipo TDBXTransaction onde você poderá efetuar o Commit e Rollback da transação.

No exemplo abaixo temos duas transações onde através de uma efetuamos 5 inserts, o resultado da query mostra que os registros estão no banco de dados e não comitados ainda, a partir dai iniciamos outra transação com o nível de isolamento ReadCommited, que quer dizer trazer todos os registrados que estejam efetivamente “comitados” no banco, como ainda não fizemos o commit, o resultados do select virá fazio, ao final efetuamos o Rollback para que os registros não sejam efetivamente gravados na base de dados e depois efetuamos um commit na transação de consulta.

O código ficaria assim:

program MultipleTransaction;
{$APPTYPE CONSOLE}

uses
  SysUtils,
  DBXDynalink,
  DBXCommon,
  DBXInterbase;

Const
  InsertSQL : String = 'Insert Into Country Values ( ''%s'', ''%s'' )';

var
  ConnName: string;
  Conn: TDBXConnection;
  TransSelect,
  TransInsert  : TDBXTransaction;
  Cmd: TDBXCommand;
  Reader: TDBXReader;
  i : integer;

begin

  Conn := TDBXConnectionFactory.GetConnectionFactory.GetConnection
    ('employee ib', 'sysdba', 'masterkey');

  if Conn <> nil then
  begin

    Cmd := Conn.CreateCommand;

    // Start transaction - only inserts
    TransInsert := Conn.BeginTransaction(TDBXIsolations.ReadCommitted);

    for I := 1 to 5 do
    begin
      Cmd.Text := Format(InsertSQL, [ 'Record ' + IntToStr(I), IntToStr(I)]);
      Cmd.Prepare;
      Cmd.ExecuteUpdate;
    end;

    // Prepare and execute the SQL Statement
    Cmd.Text := 'SELECT * FROM Country Where Country Like ''Rec%''';
    Cmd.Prepare;

    Reader := Cmd.ExecuteQuery;

    Writeln('========== First Select including the new 5 records');
    while Reader.Next do
      Writeln(Reader.Value['Country'].GetAnsiString);

    // Start new transaction - doesn't include the inserted record
    TransSelect := Conn.BeginTransaction(TDBXIsolations.DirtyRead);

    Writeln('====================================================');
    Writeln('');

    Reader := Cmd.ExecuteQuery;

    Writeln('========== Second Select based on new transaction');
    while Reader.Next do
      Writeln(Reader.Value['Country'].GetAnsiString);

    // Commit Select transaction and Rollback the Insert transaction
    Conn.CommitFreeAndNil(TransSelect);
    Conn.RollbackFreeAndNil(TransInsert);

    Readln;
    Reader.Free;
    Cmd.Free;
    Conn.Free;

  end;

end.

Ao executar o código acima, temos o seguinte resultado:

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Criando tabelas através dos recursos de metadata do dbExpress no Delphi
• Apresentações do Delphi Conference 2010 disponível para download
• Como utilizar parâmetros em dbExpress (DBX) Framework
• Copiando estrutura e dados de um DBXReader para ClientDataSet – DataSnap 2010

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

Para começar, existe uma pequena diferença ao utilizar parâmetros em SQL com DBX Framework e VCL. Enquanto a VCL utiliza “:PARAMETRO” para definir parâmetros em uma query, em DBX Framework parâmetro é representado pelo sinal de “?” e não inclui nome.

Como estamos acostumados com a VCL e certamente é muito mais legível codificar utilizando o nome dos parâmetros, você espera trabalhar da mesma forma com DBX Framework e isso é possível criando uma pequena extensão ao DBX Framework.

Para entender melhor, caso você utilize puramente o framework, seu código seria assim:

program DBX4Example;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  DBXDynalink,
  DBXCommon,
  DBXInterbase;

var

  aDBXConn: TDBXConnection;
  aDBXTrans : TDBXTransaction;
  aCmnd: TDBXCommand;
  aReader: TDBXReader;

begin

    aDBXConn := TDBXConnectionFactory.GetConnectionFactory.GetConnection('employee ib','sysdba','masterkey');

    if aDBXConn <> nil then
    begin

      aCmnd := aDBXConn.CreateCommand;

      // Start transaction
      aDBXTrans:= aDBXConn.BeginTransaction(TDBXIsolations.ReadCommitted);

      // Prepare and execute the SQL Statement
      aCmnd.Text := 'SELECT * FROM Country  Where Country = ?';
      aCmnd.Prepare;
      aCmnd.Parameters.Parameter[0].Value.SetAnsiString('USA');
      aReader := aCmnd.ExecuteQuery;

      while aReader.Next do
      begin
        Writeln( aReader.Value['Country'].GetAnsiString );
      end;

      // Commit transaction
      aDBXConn.CommitFreeAndNil(aDBXTrans);

      Readln;
      aReader.Free;
      aCmnd.Free;
      aDbxConn.Free;
    end;
end.

Veja que a query utiliza interrogação para definir o parâmetro e após o Prepare a longa linha para definir o valor do parâmetro com posição zero.

Esta primeira parte responderia a pergunta do Rafael e do Carlos, mas podemos tornar esse código mais amigável utilizando Class Helpers, recurso este que foi implementado no Delphi 2006 e nos ajuda a extender classes sem utilizar herança.

Assim sendo vou estender a classe TDBXParameterList, o qual irá permitir que eu nomeie os parâmetros e define seus respectivos valores por nome.

O código abaixo estende a classe utilizando a sintaxe class helper, veja bem isso não é herança. Esta extensão define os seguintes métodos:
SetParamatersName: este método irá receber uma lista de nomes, o qual será usado para nomear os parâmetros, você deve passar a quantidade de nomes igual a quantidade de parâmetros;
ByName: método que nos permite acessar os parâmetros através do nome, o DBX Framework traz o método GetOrdinal que permite acessar os parâmetros por nome, o ByName irá simplificar este acesso;

unit DBXParameterListHelper;

interface

uses
  DBXCommon, SysUtils;

type
  TDBXParameterListHelper = class helper for TDBXParameterList

  public
    procedure SetParamatersName(aNames: Array of String);
    function ByName( Name : String ) : TDBXWritableValue;
  end;

implementation

{ TDBXParameterListHelper }

function TDBXParameterListHelper.ByName(Name: String): TDBXWritableValue;
begin
  Result := Self.Parameter[Self.GetOrdinal(Name)].Value;
end;

procedure TDBXParameterListHelper.SetParamatersName(aNames: array of String);
var
  i: Integer;
begin

  if Length(aNames) <> Self.Count then
     raise Exception.Create('aNames should have the same number of parameters');

  for i := 0 to Self.Count - 1 do
  begin
    Self[i].Name := aNames[i];
  end;
end;

end.

Com está extensão esta parte do código:

      // Prepare and execute the SQL Statement
      aCmnd.Text := 'SELECT * FROM Country  Where Country = ?';
      aCmnd.Prepare;
      aCmnd.Parameters.Parameter[0].Value.SetAnsiString('USA');

Ficaria assim:

      // Prepare and execute the SQL Statement
      aCmnd.Text := 'SELECT * FROM Country  Where Country = ?';
      aCmnd.Prepare;
      aCmnd.Parameters.SetParamatersName(['COUNTRYNAME']);
      aCmnd.Parameters.ByName('COUNTRYNAME').SetAnsiString('USA');

Caso a query tenha vários parâmetros, ficaria assim:

      // Prepare and execute the SQL Statement
      aCmnd.Text := 'SELECT * FROM Country  Where Country = ? and Currency = ?';
      aCmnd.Prepare;
      aCmnd.Parameters.SetParamatersName(['COUNTRYNAME', 'CURRENCY']);
      aCmnd.Parameters.ByName('COUNTRYNAME').SetAnsiString('USA');
      aCmnd.Parameters.ByName('CURRENCY').SetAnsiString('Dolar');

Ao final vimos como utilizar consultas parametrizadas com DBX Framework e como utilizar class helper para estender classes.

Download do código fonte aqui.

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Criando tabelas através dos recursos de metadata do dbExpress no Delphi
• Apresentações do Delphi Conference 2010 disponível para download
• Como trabalhar com multiplas transações utilizando dbExpress Framework
• Copiando estrutura e dados de um DBXReader para ClientDataSet – DataSnap 2010

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

Existem casos onde será necessário copiar a estrutura e os dados de um DBXReader para ClientDataSet ou Params, pensando nisso no Delphi foi criada a unit DBXDBReaders.pas que traz algumas classes que permite essa operação.

A classe TDBXDataSetReader possui dois método que permitem copiar para um ClientDataSet já existente ou retorna um novo ClientDataSet, veja o exemplo abaixo.

var
  Reader: TDBXReader;
  DepClient: TDepartmentClient;
begin
  DepClient := TDepartmentClient.Create(DMClientContainer.MyDSServer.DBXConnection, False);

  try
    Reader := DepClient.GetDepartmentsOrderBy;

    try
      if Assigned(Reader) then
      begin
        TDBXDataSetReader.CopyReaderToClientDataSet(Reader, DMClientContainer.CDSCopy);
      end;
    finally
      FreeAndNil(Reader);
    end;

  finally
    DepClient.Free;
  end;

O ClientDataSet CDSCopy já existe e é parte do DataModule DMClientContainer, caso o ClientDataSet não existe, utilizar o método TDBXDataSetReader.ToClientDataSet e esta irá retornar um novo ClientDataSet.

Meus exemplos sobre DataSnap 2010 foram atualizados e você pode efetuar o download aqui.

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Apresentações do Delphi Conference 2010 disponível para download
• Disponibilizando métodos de uma classe como Server Methods sem usar TServerModule em DataSnap
• Exemplos DataSnap, dbExpress e outros recursos do Delphi 2009
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Publicando providers durante o registro dinâmico de DataSnap Server Class

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

Para uma classe ser disponibilizada como Server Methods é necessário:

• Descender de TPersistent
• Ter a diretiva {$MethodInfo ON}, esta diretiva permite ao DataSnap obter informações da classe a partir da RTTI
• Estar registrada através do componente DSServerClass

Abaixo exemplo de uma classe que não é descendente de TDSServerModule e sim de TPersistant, podemos assumir que esta classe já existia anteriormente e que agora queremos reusar em nosso servidor DataSnap

unit User;

interface

uses
  BaseServerClass,
  Classes,
  DBXCommon,
  SysUtils,
  Dialogs,
  MainServerModule;

type
{$METHODINFO ON}
  TUser = class(TPersistent)
  private

  public
    constructor Create;
    destructor Destroy; override;

    procedure AddUser(FirstLastName, Login, Password: String);

    function IsValidUser(Login, Password: String): Boolean;

    procedure DisableUser(Login: String);
    procedure EnableUser(Login: String);

  end;

implementation

uses
  ServerContainer;

{ TUser }

procedure TUser.AddUser(FirstLastName, Login, Password: String);
var
  Comm: TDBXCommand;
begin

  if (FirstLastName = '') then
    raise Exception.Create('First/Last name is required');

  if (Login = '') then
    raise Exception.Create('Login is required');

  if (Password = '') then
    raise Exception.Create('Password is required');

  Comm := FDbxConnection.CreateCommand;

  Comm.Text :=
    'Insert Into Users (NAME, LOGIN, PASSWORD, ACTIVE ) Values (' + QuotedStr
    (FirstLastName) + ',' + QuotedStr(Login) + ',' + QuotedStr(Password)
    + ', true)';
  Comm.ExecuteQuery;

  FreeAndNil(Comm);

end;

constructor TUser.Create;
begin
  FDbxConnection := DMServerContainer.DataSnap_Server_Log.DBXConnection;
end;

destructor TUser.Destroy;
begin

  inherited;
end;

procedure TUser.DisableUser(Login: String);
var
  Comm: TDBXCommand;
begin

  if (Login = '') then
    raise Exception.Create('Login is required');

  Comm := FDbxConnection.CreateCommand;

  Comm.Text := 'Update Users Set ACTIVE = False Where LOGIN = ' + QuotedStr
    (Login);
  Comm.ExecuteQuery;

  FreeAndNil(Comm);

end;

procedure TUser.EnableUser(Login: String);
var
  Comm: TDBXCommand;
begin

  if (Login = '') then
    raise Exception.Create('Login is required');

  Comm := FDbxConnection.CreateCommand;

  Comm.Text := 'Update Users Set ACTIVE = True Where LOGIN = ' + QuotedStr
    (Login);
  Comm.ExecuteQuery;

  FreeAndNil(Comm);

end;

function TUser.IsValidUser(Login, Password: String): Boolean;
var
  Comm: TDBXCommand;
  Reader: TDBXReader;
begin
  if (Login = '') then
    raise Exception.Create('Login is required');

  if (Password = '') then
    raise Exception.Create('Password is required');

  Comm := FDbxConnection.CreateCommand;

  Comm.Text := 'Select ACTIVE From Users Where LOGIN = ' + QuotedStr(Login)
    + ' and PASSWORD = ' + QuotedStr(Password);

  Reader := Comm.ExecuteQuery;

  if Reader.Next then
  begin
    Result := Reader.Value[0].GetBoolean;
  end
  else
    Result := False;

  Reader.Close;
  FreeAndNil(Reader);
  FreeAndNil(Comm);

end;

end.

Quer saber mais sobre DataSnap, clique aqui.

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Apresentações do Delphi Conference 2010 disponível para download
• Copiando estrutura e dados de um DBXReader para ClientDataSet – DataSnap 2010
• Exemplos DataSnap, dbExpress e outros recursos do Delphi 2009
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Publicando providers durante o registro dinâmico de DataSnap Server Class

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

Pretende em futuros posts, explicar mais sobre o framework.

program DBX4Example;
{$APPTYPE CONSOLE}

uses SysUtils, DBXDynalink, Dialogs, DbxInterBaseReadOnlyMetadata, DBXCommon;

var

  aConnName: string;
  aDBXConn: TDBXConnection;
  aDBXTrans: TDBXTransaction;
  aCmnd: TDBXCommand;
  aReader: TDBXReader;
  aColCount: integer;

begin

  aDBXConn := TDBXConnectionFactory.GetConnectionFactory.GetConnection
    ('EMPLOYEE IB', 'sysdba', 'masterkey');

  if aDBXConn <> nil then
  begin

    // Write the all connection parameters
    Writeln('================= Connection Properties ============');
    Writeln(aDBXConn.ConnectionProperties.Properties.Text);
    Writeln('====================================================');
    Writeln('');

    aCmnd := aDBXConn.CreateCommand;

    // Start transaction
    aDBXTrans := aDBXConn.BeginTransaction(TDBXIsolations.ReadCommitted);

    // Prepare and execute the SQL Statement
    aCmnd.Text := 'SELECT * FROM Country';
    aCmnd.Prepare;
    aReader := aCmnd.ExecuteQuery;

    aColCount := aReader.ColumnCount;
    Writeln('Results from Query: ' + aCmnd.Text);
    Writeln('Number of Columns:  ' + IntToStr(aColCount));

    while aReader.Next do
    begin
      Writeln(aReader.Value['Country'].GetAnsiString);
    end;

    Writeln('====================================================');
    Writeln('');

    // Commit transaction
    aDBXConn.CommitFreeAndNil(aDBXTrans);

    Readln;
    aReader.Free;
    aCmnd.Free;
    aDBXConn.Free;

  end;

end.

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Criando tabelas através dos recursos de metadata do dbExpress no Delphi
• Apresentações do Delphi Conference 2010 disponível para download
• Como trabalhar com multiplas transações utilizando dbExpress Framework
• Como utilizar parâmetros em dbExpress (DBX) Framework

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

A comunidade Firebird pediu e agora tem, RAD Studio 2010 traz o novo driver dbExpress para FireBird, além do suporte completo através dbExpress Framework, assista o vídeo e conheça um pouco mais.

Caso deseja mais informações sobre o RAD Studio 2010, clique aqui.

Também recomendo assistirem o novo sneak peek sobre outras novidades relacionadas com banco de dados e o novo DataSnap 2010.

Posts relacionados

• Apresentação de lançamento do Delphi 2010
• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Vídeo: Delphi XE2 e FireMonkey app no Windows, Mac e iOS
• Vídeo: Webinar o que você pode fazer com RAD Studio XE
• Vídeo: Serialização de objetos JSON – Delphi Conference 2010 Brasil

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

Inúmeras são as funcionalidades e benefícios de se utilizar o dbExpress Framework para este fim, para começar vamos ver como criar tabelas utilizando utilizando o framework.

Para começar você precisamos definir a conexão com o banco de dados, geralmente utilizamos o SQLConnection ou o DBXConnection, é a partir da conexão que o dbExpress sabe com que banco de dados está conectado e assim saberá como gerar os scripts de criação da tabela. Definida a conexão instanciamos a classe TDBXDataExpressMetaDataProvider, que será o interlocutor entre as classes de metadata e a conexão.

function DBXGetMetaProvider(const AConnection: TDBXConnection):  TDBXDataExpressMetaDataProvider;
var
   Provider: TDBXDataExpressMetaDataProvider;
begin
  Provider := TDBXDataExpressMetaDataProvider.Create;
  try
    Provider.Connection := AConnection;
    Provider.Open;
  except
    FreeAndNil(Provider);
    raise;
  end;

  Result := Provider;
end;

Esta função irá receber a conexão, neste caso estamos passando a instância do DBXConnection, no caso de você estar utilizando SQLConnection não tem problema, pois o SQLConnection fornece a sua instância DBXConnection.

Agora basta criamos a tabela utilizando a classe TDBXMetaDataTable e as colunas através da classe TBX<XXX>Column, onde XXX é o tipo da coluna, para cada tipo de coluna no banco de dados o dbExpress Framework terá uma representação. A seguir a criação da tabela PAIS e seus respectivos campos.

var
  Provider: TDBXDataExpressMetaDataProvider;
  Pais     : TDBXMetaDataTable;
  PaisID   : TDBXInt32Column;
  StrField : TDBXUnicodeVarCharColumn;
begin
  Provider := DBXGetMetaProvider(conn.DBXConnection);

  // Pais
  Pais := TDBXMetaDataTable.Create;
  Pais.TableName := 'PAIS';

  // Campo ID do País
  PaisIdField := TDBXInt32Column.Create('PAISID');
  PaisIdField.Nullable := false;
  PaisIdField.AutoIncrement := true;
  Pais.AddColumn(JobIdField);

  // Campo nome do País
  StrField := TDBXUnicodeVarCharColumn.Create('NOME_PAIS', 50);
  StrField.Nullable := False;
  Pais.AddColumn(StrField);

  // Campo sigla do País
  StrField := TDBXUnicodeVarCharColumn.Create('SIGLA', 2);
  StrField.Nullable := False;
  Pais.AddColumn(StrField);

  // Cria a tabela
  Provider.CreateTable(Pais);

Com a tabela e campos definido o provider executa o método CreateTable para a efetuar a criação da mesma no banco, a partir do momento que mudamos a conexão para outro banco de dados não será necessário atualizar este código, pois o dbExpress é responsável por definir o script de acordo com o banco.

Para criar primary key, foreign key, indices, etc.. disponibilizei um exemplo completo no Embarcadero Code Central, para fazer o download clique aqui

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Criando tabelas através dos recursos de metadata do dbExpress no Delphi
• Apresentações do Delphi Conference 2010 disponível para download
• Como trabalhar com multiplas transações utilizando dbExpress Framework
• Como utilizar parâmetros em dbExpress (DBX) Framework

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse

Este exemplo mostra diversos novos recursos do Delphi 2009, são eles:

1. DataSnap
   • Servidor DataSnap
   • Autenticação através do servidor de aplicação consultando banco de dados
   • Server methodos – métodos disponibilizados no servidor para acesso através das aplicações cliente
   • Client DataSnap
   • Execução de server methods a partir do cliente
   • Utilização de clientdataset no lado cliente, assim como applyupdates e master detail
2. dbExpress
   • Criando tabelas, primary key e foreign key através de dbExpress framework
3. Utilização de resources
   • Carregando recursos (images PNG) dinamicamente na aplicação

Pretendo atualizar esta aplicação frequentemente, o objetivo é exemplificar a utilização do DataSnap e dbExpress.

Se você tem alguma sugestão do que podemos adicionar nesta aplicação, por favor comente aqui no meu blog.

Posts relacionados

• CopyReaderToClientDataSet, Blob e a mensagem “Feature not implemented”
• Apresentações do Delphi Conference 2010 disponível para download
• Copiando estrutura e dados de um DBXReader para ClientDataSet – DataSnap 2010
• Disponibilizando métodos de uma classe como Server Methods sem usar TServerModule em DataSnap
• Conectando ao PostgreSQL com dbExpress ODBC driver
• Publicando providers durante o registro dinâmico de DataSnap Server Class

Andreano Lanusse | Tecnologia e Desenvolvimento de Software
Follow me on Twitter: @andreanolanusse